home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / T-TPUG Old Monthly Disks / (c)t1.d64 / dialer.c (.txt) < prev    next >
Commodore BASIC  |  2007-02-04  |  1KB  |  61 lines
  1. 10 REM TOUCH-TONE DIALER
  2. 20 REM BY BOB HUFFMAN
  3. 30 :
  4. 40 REM TORONTO BBS NUMBERS BY RICHARD BRADLEY
  5. 50 DIM B$(50),C$(50)
  6. 100 DATA TPUG,223-2625
  7. 110 DATA PSI,624-5431
  8. 120 DATA NORTEC,487-5833
  9. 130 DATA CFTR,366-2069
  10. 140 DATA RTC,884-4165
  11. 990 DATA 0,0
  12. 992 POKE 53281,15:POKE 53280,12
  13. 993 PRINT CHR$(147)CHR$(151)
  14. 1000 P=1
  15. 1010 READ B$(P),C$(P)
  16. 1020 IF B$(P)="0" THEN 1040
  17. 1030 P=P+1:GOTO 1010
  18. 1040 PM=P-1:CF=.975:K=.059604645
  19. 1050 FOR N=0 TO 3:READ F:F=F*CF/K
  20. 1060 RH(N)=INT(F/256):RL(N)=F-256*RH(N):NEXT
  21. 1070 DATA 697,770,852,941
  22. 1080 FOR N=0 TO 2:READ F:F=F*CF/K
  23. 1090 CH(N)=INT(F/256):CL(N)=F-256*CH(N):NEXT
  24. 1091 DATA 1209,1336,1477
  25. 1092 V1=54272:V2=V1+7:POKE V1+24,15
  26. 1093 POKE V1+5,0:POKE V1+6,240
  27. 1094 POKE V2+5,0:POKE V2+6,240
  28. 1100 P=1
  29. 1110 PRINT CHR$(147)"KEY  PARTY"TAB(27)"NUMBER":PRINT
  30. 1120 IF B$(P)="0" THEN 1220
  31. 1130 PRINT P;TAB(4)B$(P);TAB(23)C$(P)
  32. 1140 P=P+1
  33. 1150 IF (P-1)/18=INT((P-1)/18) THEN 1170
  34. 1160 GOTO1120
  35. 1170 PRINT:INPUT "ENTER KEY OR RETURN FOR NEXT PAGE";A$
  36. 1180 A=VAL(A$+CHR$(0))
  37. 1190 IF A=0 THEN 1110
  38. 1200 IF A>PM THEN PRINT"TRY AGAIN":A$="":GOTO 1170
  39. 1210 NB$=C$(A):GOTO 1270
  40. 1220 PRINT:INPUT "ENTER KEY OR RETURN TO END";A$
  41. 1230 A=VAL(A$+CHR$(0))
  42. 1235 IF A$="R" THEN P=1:A$="":GOTO 1110
  43. 1240 IF A=0 THEN END
  44. 1250 IF A>PM THEN PRINT"TRY AGAIN":A$="":GOTO 1220
  45. 1260 NB$=C$(A)
  46. 1270 FOR J=1 TO LEN(NB$)
  47. 1280 N$=MID$(NB$,J,1)
  48. 1290 IF N$="0" THEN N$="11"
  49. 1300 IF N$="*" THEN N$="10"
  50. 1310 IF N$="#" THEN N$="12"
  51. 1320 IF N$=" "ORN$="-"ORN$="("ORN$=")"THEN 1410
  52. 1330 VA=VAL(N$)-1
  53. 1340 R%=VA/3
  54. 1350 C%=VA-3*R%
  55. 1360 POKE V1+1,RH(R%):POKE V1,RL(R%)
  56. 1370 POKE V2+1,CH(C%):POKE V2,CL(C%)
  57. 1380 POKE V1+4,17:POKE V2+4,17
  58. 1390 FOR N=1 TO 100:NEXT
  59. 1400 POKE V1+4,0:POKE V2+4,0
  60. 1410 NEXT:P=1:A$="":GOTO 1110
  61.